# Maintainer: IntelligentWolf Ltd <paul@wolf.uk.com>
pkgname=wolfviewer-bin
pkgver=7.2.4.65
pkgrel=1
pkgdesc="Wolf Territories viewer for OpenSimulator virtual worlds (Firestorm-based)"
arch=('x86_64')
url="https://www.wolf-grid.com/"
license=('LGPL-2.1-only')
depends=('alsa-lib' 'at-spi2-core' 'cairo' 'dbus' 'expat' 'fontconfig' 'glib2' 'glibc' 'glu' 'libcups' 'libgcc' 'libglvnd' 'libstdc++' 'libx11' 'libxcb' 'libxcomposite' 'libxcrypt-compat' 'libxdamage' 'libxext' 'libxfixes' 'libxkbcommon' 'libxrandr' 'mesa' 'nspr' 'nss' 'pango' 'systemd-libs' 'util-linux-libs' 'wayland')
provides=('wolfviewer')
conflicts=('wolfviewer')
options=('!strip' '!debug' '!lto' '!emptydirs')
install=wolfviewer.install
source=("WolfViewer-7.2.4.65.tar.xz::https://wolf-grid.com/downloads/wolfviewer/w65/WolfViewer-7.2.4-linux64-OpenSim.tar.xz")
sha256sums=('0c9883438e870718134cd5b025184ff44d40c413ccbfaffbeabbae2ee83e6cc9')

package() {
    local top
    top="$(find "$srcdir" -mindepth 1 -maxdepth 1 -type d | head -1)"
    install -d "$pkgdir/opt"
    cp -a "$top" "$pkgdir/opt/wolfviewer"
    printf 'Installed with makepkg from wolfviewer-bin (the AUR, or wolf-grid.com/linux/aur). Update it the same way; the viewer does not update itself.\n' \
        > "$pkgdir/opt/wolfviewer/etc/wolfviewer-package"
    install -Dm755 /dev/stdin "$pkgdir/usr/bin/wolfviewer" <<'SH'
#!/bin/sh
exec /opt/wolfviewer/wolfviewer "$@"
SH
    install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/wolfviewer.desktop" <<'DE'
[Desktop Entry]
Name=WolfViewer
GenericName=Virtual World Viewer
Comment=Client for accessing 3D virtual worlds
Exec=/opt/wolfviewer/wolfviewer
Icon=wolfviewer
Terminal=false
Type=Application
Categories=Network;Game;
StartupNotify=true
StartupWMClass=do-not-directly-run-wolfviewer-bin
DE
    install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/wolfviewer-url-handler.desktop" <<'DE'
[Desktop Entry]
Name=WolfViewer (links)
Comment=Opens secondlife://, hop:// and x-grid-location-info:// links in WolfViewer
Exec=/opt/wolfviewer/etc/handle_secondlifeprotocol.sh %u
Icon=wolfviewer
Terminal=false
Type=Application
NoDisplay=true
MimeType=x-scheme-handler/secondlife;x-scheme-handler/hop;x-scheme-handler/x-grid-location-info;
DE
    install -Dm644 "$pkgdir/opt/wolfviewer/wolfviewer_icon.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/wolfviewer.png"
    install -Dm644 "$pkgdir/opt/wolfviewer/wolfviewer_48.png" "$pkgdir/usr/share/icons/hicolor/48x48/apps/wolfviewer.png"
}