LSL Guide

Example

// Bus driver - Wolf Territories, wolfNPC (DRIVE, PARK, EXIT), wolfNPCInfo and WOLF_NPC_DRIVE.
//
// Make a person in WolfAvatars, put them on your land with Wolf World > WolfNPC next to your bus
// (any vehicle with a seat: the first prim with a sit target is the driver's seat, the others are
// for passengers), and drop this script into the driver. Say on channel 5 (owner only):
//   /5 drive    the driver finds the bus called BUS within 20 m, gets in and drives the ROUTE
//               round and round, following the ground, slowing for bends and stopping for anyone
//               in the road
//   /5 park     stops where it is (the driver stays in the seat)
//   /5 go       drives on
//   /5 out      the driver gets out and stands beside the bus, which stays where it stopped
//   /5 where    what the driver is doing, and the route it drives
// Anyone who comes up to the bus is greeted, once each visit.
//
// Rules the grid keeps: the bus must be yours, or have wolfnpc-driver in its root prim's
// description; only people drive; the driver's seat must be free. A route has 2 to 64 points
// (region x,y,z; the heights do not matter); end it with ;back instead of ;loop to drive there
// and back again. To give the driver a new route, change ROUTE and say /5 drive again: it takes
// the new one at once, carrying on from the route point nearest the bus.

string BUS = "Bus";             // the name of your bus
string ROUTE = "40,40,22;200,40,22;200,200,22;40,200,22;loop";
integer CHANNEL = 5;

npc(string command, string value)
{
    if (!wolfNPC(command, value))
        llOwnerSay(command + " refused: " + wolfGetLastError());
}

default
{
    state_entry()
    {
        llListen(CHANNEL, "", llGetOwner(), "");
        npc("WHEN", "near|*|6|say:Hop on! Next stop, the harbour.;once=visit;id=fare");
    }

    on_rez(integer p)
    {
        llResetScript();
    }

    listen(integer ch, string name, key id, string msg)
    {
        msg = llToLower(llStringTrim(msg, STRING_TRIM));
        if (msg == "drive")
            llSensor(BUS, NULL_KEY, ACTIVE | PASSIVE | SCRIPTED, 20.0, PI);
        else if (msg == "park")
            npc("PARK", "");
        else if (msg == "go")
            npc("PARK", "0");
        else if (msg == "out")
            npc("EXIT", "");
        else if (msg == "where")
        {
            string cfg = wolfNPCInfo("CFG");
            llOwnerSay("Doing: " + wolfNPCInfo("INTENT")
                + "; route: " + llJsonGetValue(cfg, ["vehicle", "route"]));
        }
    }

    sensor(integer n)
    {
        npc("DRIVE", (string)llDetectedKey(0) + "|" + ROUTE);
    }

    no_sensor()
    {
        llOwnerSay("There is no bus called " + BUS + " within 20 m.");
    }
}

In the bus itself: an engine sound and a sign while an NPC drives it

default
{
    link_message(integer sender, integer num, string str, key id)
    {
        if (num != WOLF_NPC_DRIVE)
            return;                                   // id is the driver NPC's key
        list f = llParseString2List(str, ["|"], []);
        string what = llList2String(f, 0);
        if (what == "start")
        {
            llLoopSound("engine", 0.6);               // a sound in the bus's Contents
            llSetText("In service", <1.0, 0.8, 0.2>, 1.0);
        }
        else if (what == "leg")
        {
            float speed = llList2Float(f, 1);         // m/s for this stretch
            float turn = llList2Float(f, 2);          // degrees a second, more than 0 = left
            if (turn > 10.0) llSetText("Turning left", <1.0, 0.8, 0.2>, 1.0);
            else if (turn < -10.0) llSetText("Turning right", <1.0, 0.8, 0.2>, 1.0);
            else llSetText("In service - " + (string)llRound(speed * 3.6) + " km/h", <1.0, 0.8, 0.2>, 1.0);
        }
        else if (what == "park")
            llSetText("Stopped", <1.0, 0.8, 0.2>, 1.0);
        else if (what == "exit")
        {
            llStopSound();
            llSetText("", ZERO_VECTOR, 0.0);
        }
    }
}

Is it awake, alive, and how hurt?

list s = llParseStringKeepNulls(wolfNPCInfo("STATE"), ["|"], []);
if (llList2String(s, 2) == "dead")
    llOwnerSay("Down until its respawn time.");
else
    llOwnerSay("Health " + llList2String(s, 3) + ", " + llList2String(s, 1));